mirror of https://gitee.com/openkylin/linux.git
101 lines
2.4 KiB
ArmAsm
101 lines
2.4 KiB
ArmAsm
|
/*
|
||
|
|
* GNU linker script for the VDSO library.
|
||
|
|
*
|
||
|
|
* Copyright (C) 2012 ARM Limited
|
||
|
|
*
|
||
|
|
* This program is free software; you can redistribute it and/or modify
|
||
|
|
* it under the terms of the GNU General Public License version 2 as
|
||
|
|
* published by the Free Software Foundation.
|
||
|
|
*
|
||
|
|
* This program is distributed in the hope that it will be useful,
|
||
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
|
|
* GNU General Public License for more details.
|
||
|
|
*
|
||
|
|
* You should have received a copy of the GNU General Public License
|
||
|
|
* along with this program. If not, see <http://www.gnu.org/licenses/>.
|
||
|
|
*
|
||
|
|
* Author: Will Deacon <will.deacon@arm.com>
|
||
|
|
* Heavily based on the vDSO linker scripts for other archs.
|
||
|
|
*/
|
||
|
|
|
||
|
|
#include <linux/const.h>
|
||
|
|
#include <asm/page.h>
|
||
|
|
#include <asm/vdso.h>
|
||
|
|
|
||
|
|
OUTPUT_FORMAT("elf64-littleaarch64", "elf64-bigaarch64", "elf64-littleaarch64")
|
||
|
|
OUTPUT_ARCH(aarch64)
|
||
|
|
|
||
|
|
SECTIONS
|
||
|
|
{
|
||
|
|
. = VDSO_LBASE + SIZEOF_HEADERS;
|
||
|
|
|
||
|
|
.hash : { *(.hash) } :text
|
||
|
|
.gnu.hash : { *(.gnu.hash) }
|
||
|
|
.dynsym : { *(.dynsym) }
|
||
|
|
.dynstr : { *(.dynstr) }
|
||
|
|
.gnu.version : { *(.gnu.version) }
|
||
|
|
.gnu.version_d : { *(.gnu.version_d) }
|
||
|
|
.gnu.version_r : { *(.gnu.version_r) }
|
||
|
|
|
||
|
|
.note : { *(.note.*) } :text :note
|
||
|
|
|
||
|
|
. = ALIGN(16);
|
||
|
|
|
||
|
|
.text : { *(.text*) } :text =0xd503201f
|
||
|
|
PROVIDE (__etext = .);
|
||
|
|
PROVIDE (_etext = .);
|
||
|
|
PROVIDE (etext = .);
|
||
|
|
|
||
|
|
.eh_frame_hdr : { *(.eh_frame_hdr) } :text :eh_frame_hdr
|
||
|
|
.eh_frame : { KEEP (*(.eh_frame)) } :text
|
||
|
|
|
||
|
|
.dynamic : { *(.dynamic) } :text :dynamic
|
||
|
|
|
||
|
|
.rodata : { *(.rodata*) } :text
|
||
|
|
|
||
|
|
_end = .;
|
||
|
|
PROVIDE(end = .);
|
||
|
|
|
||
|
|
. = ALIGN(PAGE_SIZE);
|
||
|
|
PROVIDE(_vdso_data = .);
|
||
|
|
|
||
|
|
/DISCARD/ : {
|
||
|
|
*(.note.GNU-stack)
|
||
|
|
*(.data .data.* .gnu.linkonce.d.* .sdata*)
|
||
|
|
*(.bss .sbss .dynbss .dynsbss)
|
||
|
|
}
|
||
|
|
}
|
||
|
|
|
||
|
|
/*
|
||
|
|
* We must supply the ELF program headers explicitly to get just one
|
||
|
|
* PT_LOAD segment, and set the flags explicitly to make segments read-only.
|
||
|
|
*/
|
||
|
|
PHDRS
|
||
|
|
{
|
||
|
|
text PT_LOAD FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
|
||
|
|
dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
|
||
|
|
note PT_NOTE FLAGS(4); /* PF_R */
|
||
|
|
eh_frame_hdr PT_GNU_EH_FRAME;
|
||
|
|
}
|
||
|
|
|
||
|
|
/*
|
||
|
|
* This controls what symbols we export from the DSO.
|
||
|
|
*/
|
||
|
|
VERSION
|
||
|
|
{
|
||
|
|
LINUX_2.6.39 {
|
||
|
|
global:
|
||
|
|
__kernel_rt_sigreturn;
|
||
|
|
__kernel_gettimeofday;
|
||
|
|
__kernel_clock_gettime;
|
||
|
|
__kernel_clock_getres;
|
||
|
|
local: *;
|
||
|
|
};
|
||
|
|
}
|
||
|
|
|
||
|
|
/*
|
||
|
|
* Make the sigreturn code visible to the kernel.
|
||
|
|
*/
|
||
|
|
VDSO_sigtramp = __kernel_rt_sigreturn;
|