ukui-menu/qml/AppUI/FullScreenUI.qml

import QtQuick 2.0
import QtQuick.Layouts 1.12
import org.ukui.quick.items 1.0 as UkuiItems
import org.ukui.menu.core 1.0

UkuiItems.StyleBackground {
    paletteRole: UkuiItems.Theme.Dark
    MouseArea {
        anchors.fill: parent
        onClicked: {
            if (fullScreenContent.visible) {
                //执行全屏退出操作
                forceActiveFocus();
                mainWindow.hide();
            } else {
                folderLoader.isFolderOpened = false;
                fullScreenContent.visible = true;
                fullScreenContent.isContentShow = true;
            }
        }
    }

    ColumnLayout {
        anchors.fill: parent
        anchors.leftMargin: 35
        anchors.rightMargin: 35

        FullScreenHeader {
            id: fullScreenHeader
            Layout.preferredHeight: 130
            Layout.fillWidth: true
            Layout.maximumHeight: 130
            searchOpacity: fullScreenContent.isContentShow ? 1 : 0
        }

        Item {
            Layout.fillHeight: true
            Layout.fillWidth: true

            FullScreenContent {
                id: fullScreenContent
                anchors.fill: parent
                Component.onCompleted: folderLoader.turnPageFinished.connect(contentShowFinished)
                Component.onDestruction: folderLoader.turnPageFinished.disconnect(contentShowFinished)
            }

            FullScreenFolder {
                id: folderLoader
                anchors.fill: parent
                Component.onCompleted: fullScreenContent.openFolderSignal.connect(initFolder)
                Component.onDestruction: fullScreenContent.openFolderSignal.disconnect(initFolder)
            }
        }

        FullScreenFooter {
            Layout.preferredHeight: 90
            Layout.fillWidth: true
        }
    }
}