ukui-menu/qml/AppUI/Sidebar.qml

import QtQuick 2.0
import QtQuick.Layouts 1.12

Item {
    ColumnLayout {
        anchors.fill: parent
        anchors.topMargin: 12

        Row {
            Layout.fillWidth: true
            Layout.preferredHeight: 40
            Layout.rightMargin: 12

            ListView {
                id: extensionListView
                width: parent.width - 34
                height: parent.height
                orientation: ListView.Horizontal
                model: extensionManager.extensionModel()
                delegate: headerDelegate

                function send(data) {
                    if (currentItem !== null) {
                        model.send(currentIndex, data);
                    }
                }

                onCurrentIndexChanged: {
                    if (currentItem !== null) {
                        currentItem.select();
                    }
                }
            }

            Item {
                width: 34
                height: 34
            }
        }
        Item {
            Layout.fillWidth: true
            Layout.fillHeight: true

            Loader {
                id: extensionLoader
                anchors.fill: parent
                clip: true
                focus: true
                onLoaded: {
                    item.send.connect(extensionListView.send);
                }
            }
        }

        Row {
            Layout.fillWidth: true
            Layout.preferredHeight: 40
            Layout.rightMargin: 12
            layoutDirection: Qt.RightToLeft

            Item {
                width: 32
                height: 32
            }
        }
    }

    Component {
        id: headerDelegate

        Item {
            property var extensionData: model.data
            width: 100
            height: ListView.view ? ListView.view.height : 0

            onExtensionDataChanged: {
                if (extensionLoader.source === model.url) {
                    extensionLoader.item.extensionData = extensionData;
                }
            }

            function select() {
                if (extensionLoader.source !== model.url) {
                    extensionLoader.setSource(model.url, {extensionData: extensionData});
                }
            }

            Text {
                anchors.fill: parent
                verticalAlignment: Text.AlignVCenter
                horizontalAlignment: Text.AlignHCenter
                font.bold: true
                wrapMode: Text.ElideRight

                color: parent.ListView.isCurrentItem ? "blue" : "black"
                text: model.name
            }

            MouseArea {
                anchors.fill: parent
                onClicked: {
                    parent.ListView.view.currentIndex = model.index;
                }
            }
        }
    }

    Component.onCompleted: {
        if (extensionListView.count > 0) {
            extensionListView.currentIndex = 0;
        }
    }
}