TEMPLATE = lib
TARGET = ukui-qml-style-helper
QT += KConfigCore Kirigami2 quick widgets

CONFIG += plugin c++11 link_pkgconfig

TARGET = $$qtLibraryTarget($$TARGET)
uri = org.ukui.qqc2style.private

PKGCONFIG += gsettings-qt
INCLUDEPATH += /usr/include/KF5/Kirigami2
LIBS += -L/usr/lib -L$$[QT_INSTALL_LIBS] -lKF5Kirigami2

include(../libqt5-ukui-style/effects/effects.pri)

# Input
SOURCES += \
        KyIcon.cpp \
        kyquickstyleitem.cpp \
        kystylehelper.cpp \
        qqc2styleplugin.cpp

HEADERS += \
        KyIcon.h \
        kyquickpadding_p.h \
        kyquickstyleitem.h \
        kystylehelper.h \
        qqc2styleplugin.h

DISTFILES = qmldir

!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
    copy_qmldir.target = $$OUT_PWD/qmldir
    copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
    copy_qmldir.commands = $(COPY_FILE) "$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)" "$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)"
    QMAKE_EXTRA_TARGETS += copy_qmldir
    PRE_TARGETDEPS += $$copy_qmldir.target
}

qmldir.files = qmldir
unix {
#    installPath = $$[QT_INSTALL_QML]/$$replace(uri, \., /)
    installPath = $$[QT_INSTALL_LIBS]/qt5/qml/org/ukui/qqc2style/private/
    qmldir.path = $$installPath
    target.path = $$installPath
    INSTALLS += target qmldir
}