ukui-search/frontend/frontend.pro

QT       += core gui dbus KWindowSystem xml x11extras sql

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

VERSION = 2.2.3
DEFINES += VERSION='\\"$${VERSION}\\"'
TARGET = ukui-search
TEMPLATE = app

PKGCONFIG += gio-2.0 glib-2.0 gio-unix-2.0 kysdk-waylandhelper
CONFIG += c++11 link_pkgconfig no_keywords lrelease
LIBS += -lxapian -lgsettings-qt -lquazip5 -lX11
LIBS += -lukui-appwidget-manager -lukui-appwidget-provider
#LIBS += -lukui-log4qt
# The following define makes your compiler emit warnings if you use
# any Qt feature that has been marked deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0
include(../libsearch/libukui-search-headers.pri)
include(control/control.pri)
include(model/model.pri)
include(xatom/xatom.pri)
include(../3rd-parties/qtsingleapplication/qtsingleapplication.pri)
include(view/view.pri)
include(search-app-widget-plugin/search-app-widget-plugin.pri)


SOURCES += \
    main.cpp \
    mainwindow.cpp \
    ukui-search-dbus-service.cpp \
    ukui-search-gui.cpp


HEADERS += \
    mainwindow.h \
    ukui-search-dbus-service.h \
    ukui-search-gui.h

# Default rules for deployment.

target.path = /usr/bin
!isEmpty(target.path): INSTALLS += target

data-menu.path = /usr/share/applications
data-menu.files += ../data/ukui-search-menu.desktop
data.path = /etc/xdg/autostart
data.files += ../data/ukui-search.desktop

INSTALLS += data data-menu

RESOURCES += \
    resource.qrc \
    search-app-widget-plugin/provider/src.qrc

TRANSLATIONS += \
    ../translations/ukui-search/zh_CN.ts \
    ../translations/ukui-search/tr.ts \
    ../translations/ukui-search/bo_CN.ts \
    ../translations/ukui-search/appwidget/search_zh_CN.ts \
    ../translations/ukui-search/appwidget/search_bo_CN.ts

qm_files.path = /usr/share/ukui-search/translations/
qm_files.files = $$OUT_PWD/.qm/zh_CN.qm \
                 $$OUT_PWD/.qm/bo_CN.qm \
                 $$OUT_PWD/.qm/tr.qm \

schemes.path =  /usr/share/glib-2.0/schemas/
schemes.files += ../data/org.ukui.log4qt.ukui-search.gschema.xml

appwidget_qm_files.files = $$OUT_PWD/.qm/search_bo_CN.qm \
                           $$OUT_PWD/.qm/search_zh_CN.qm
appwidget_qm_files.path = /usr/share/appwidget/translations/

qml.files += search-app-widget-plugin/provider/data/search.qml
qml.path = /usr/share/appwidget/qml/

appwidgetconf.files  += search-app-widget-plugin/provider/data/search.conf
appwidgetconf.path = /usr/share/appwidget/config/

service.files += search-app-widget-plugin/provider/org.ukui.appwidget.provider.search.service
service.path += /usr/share/dbus-1/services/

preview.files += search-app-widget-plugin/provider/data/search.png
preview.path = /usr/share/appwidget/search/

svg.files += search-app-widget-plugin/provider/data/ukui-search.svg
svg.path = /usr/share/appwidget/search/

INSTALLS += qm_files schemes qml appwidget_qm_files appwidgetconf service preview svg

LIBS += -L$$OUT_PWD/../libchinese-segmentation -lchinese-segmentation \
        -L$$OUT_PWD/../libsearch -lukui-search

INCLUDEPATH += $$PWD/../libchinese-segmentation
DEPENDPATH += $$PWD/../libchinese-segmentation

DISTFILES += \
    ../data/org.ukui.log4qt.ukui-search.gschema.xml \