buildscript {
    ext {
        springBootVersion = '2.2.1.RELEASE'
    }
    repositories {
        mavenLocal() //优先查找本地maven库，性能最好
        maven{ url 'http://maven.aliyun.com/nexus/content/groups/public/'}
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}
// 全局配置
allprojects {
    group 'com.diboot'
    version '2.0.3'
    apply plugin: 'idea'
}
// 子项目的配置
subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'java-library'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    
    [compileJava,compileTestJava,javadoc]*.options*.encoding = 'UTF-8'
    repositories {
        mavenLocal() //优先查找本地maven库，性能最好
        maven{ url 'http://maven.aliyun.com/nexus/content/groups/public/'}
    }
    ext {//依赖版本
        springBootVersion = "2.2.1.RELEASE"
        mysqlConnectorVersion = "8.0.16"
        mybatisPlusVersion = "3.2.0"
        fastjsonVersion = "1.2.60"
        lombokVersion = "1.18.10"
        validatorVersion = "6.0.18.Final"
    }
    dependencies {
        // Gradle 5.0及以上版本，使用如下方式
//        annotationProcessor("org.projectlombok:lombok:$lombokVersion")
        //gradle 5.0版本以下，使用如下方式
        compileOnly("org.projectlombok:lombok:$lombokVersion")

        compile("javax.servlet:javax.servlet-api:4.0.1")
        compile("org.springframework.boot:spring-boot-starter-web:$springBootVersion")
        // Mybatis-Plus
        compile("com.baomidou:mybatis-plus-boot-starter:$mybatisPlusVersion")
        // Log4j2
        compile("org.springframework.boot:spring-boot-starter-log4j2:$springBootVersion")
        // JDBC Driver
        compile("mysql:mysql-connector-java:$mysqlConnectorVersion")
        // JSON
        compile("com.alibaba:fastjson:$fastjsonVersion")
        // 数据校验
        compile("org.hibernate.validator:hibernate-validator:$validatorVersion")
        // Apache Commons
        compile("org.apache.commons:commons-lang3:3.8.1",
               // "commons-fileupload:commons-fileupload:1.3.3",
                "commons-io:commons-io:2.6")
        
        // 单元测试
        testCompile("org.springframework.boot:spring-boot-starter-test:$springBootVersion")
        testCompile("junit:junit:4.12")
    }
    configurations {
        //移除spring boot 默认logger依赖
        all*.exclude module: 'spring-boot-starter-logging'
    }
}