ukui-menu/qml/AppUI/Sidebar.qml

/*
 * Copyright (C) 2023, KylinSoft Co., Ltd.
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 *
 */

import QtQml 2.12
import QtQuick 2.12
import QtQuick.Layouts 1.12
import QtQuick.Controls 2.5

import org.ukui.menu.core 1.0
import org.ukui.menu.utils 1.0
import org.ukui.menu.extension 1.0
import org.ukui.quick.items 1.0 as UkuiItems

Item {
    ColumnLayout {
        id: sidebarLayout

        anchors.fill: parent
        anchors.topMargin: 12
        anchors.bottomMargin: 12
        spacing: 0

        MouseArea {
            id: fullScreenbutton

            Layout.preferredWidth: 36
            Layout.preferredHeight: 36
            Layout.alignment: Qt.AlignHCenter | Qt.AlignTop

            ToolTip.delay: 500
            ToolTip.text: qsTr("Expand")
            ToolTip.visible: containsMouse

            visible: !isLiteMode
            hoverEnabled: true
            activeFocusOnTab: true

            onClicked: mainWindow.isFullScreen = true
            Keys.onPressed: {
                if (event.key === Qt.Key_Enter || event.key === Qt.Key_Return) {
                    mainWindow.isFullScreen = true;
                }
            }

            UkuiItems.StyleBackground {
                anchors.fill: parent
                radius: 4
                useStyleTransparency: false
                paletteRole: UkuiItems.Theme.Button
                alpha: parent.containsPress ? 1 : parent.containsMouse ? 0.7 : 0
                borderColor: UkuiItems.Theme.Highlight
                border.width: parent.activeFocus ? 2 : 0

                ThemeIcon {
                    anchors.centerIn: parent
                    width: 16; height: 16
                    source: "view-fullscreen-symbolic"
                }
            }
        }

        MouseArea {
            id: powerButton
            Layout.preferredWidth: 36
            Layout.preferredHeight: 36
            Layout.alignment: Qt.AlignHCenter | Qt.AlignBottom

            ToolTip.delay: 500
            ToolTip.visible: containsMouse
            ToolTip.text: powerButtonBase.toolTip

            hoverEnabled: true
            activeFocusOnTab: true
            acceptedButtons: Qt.LeftButton | Qt.RightButton
            property int spacingFromMenu: 16

            Keys.onPressed: {
                if (event.key === Qt.Key_Enter || event.key === Qt.Key_Return) {
                    powerButtonBase.clicked(true, 0, 0, mainWindow.isFullScreen);
                }
            }

            onClicked: {
                var buttonPosition = mapToGlobal(width, height);
                powerButtonBase.clicked(mouse.button === Qt.LeftButton, buttonPosition.x + spacingFromMenu, buttonPosition.y + spacingFromMenu, mainWindow.isFullScreen);
            }

            UkuiItems.StyleBackground {
                anchors.fill: parent
                paletteRole: UkuiItems.Theme.Button
                useStyleTransparency: false
                alpha: parent.containsPress ? 1 : parent.containsMouse ? 0.7 : 0
                radius: 4
                borderColor: UkuiItems.Theme.Highlight
                border.width: parent.activeFocus ? 2 : 0

                PowerButton {
                    id: powerButtonBase
                }

                ThemeIcon {
                    anchors.centerIn: parent
                    width: 16
                    height: 16
                    source: powerButtonBase.icon
                }
            }
        }
    }
}